ARCHLINUX не собирается boost 1.58 через PKGBUILD

./boost/python/detail/wrap_python.hpp:50:11: фатальная ошибка: pyconfig.h: Нет такого файла или каталога

-I"/usr/include/python3.4m"

libs/mpi/src/python/py_nonblocking.cpp: In function 'bool {anonymous}::wrap_test_all({anonymous}::request_list&, boost::python::api::object)':
libs/mpi/src/python/py_nonblocking.cpp:167:63: error: cannot convert 'boost::optional<{anonymous}::py_call_output_iterator<boost::mpi::status, __gnu_cxx::__normal_iterator<boost::mpi::python::request_with_value*, std::vector<boost::mpi::python::request_with_value> > > >' to 'bool' in return
           status_value_iterator(py_callable, requests.begin()));

# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: kevin <kevin@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Kritoke <kritoke@gamebox.net>
# Contributor: Luca Roccia <little_rock@users.sourceforge.net>

pkgbase=boost
pkgname=('boost-libs58' 'boost58')
pkgver=1.58.0
_boostver=${pkgver//./_}
pkgrel=3
url='http://www.boost.org/'
arch=('i686' 'x86_64')
license=('custom')
makedepends=('icu>=55.1' 'python' 'python2' 'bzip2' 'zlib' 'openmpi')
source=(https://downloads.sourceforge.net/project/${pkgbase}/${pkgbase}/${pkgver}/${pkgbase}_${_boostver}.tar.bz2
        https://svn.boost.org/trac10/raw-attachment/ticket/10282/py_nonblocking.patch
        boost-1.58.0-Fix-for-bind-void-mf-ambiguous-resolution-error.patch)
sha1sums=('2fc96c1651ac6fe9859b678b165bd78dc211e881'
          '903ed0bfcc9f716127c60f7bf6a7e8c0d2ee9939'
          'f78d9c6a1ca0c073c21a74d01e6f72e3eb1d8d80')

prepare() {
   cd ${pkgbase}_${_boostver}

   patch -p2 -i ../boost-1.58.0-Fix-for-bind-void-mf-ambiguous-resolution-error.patch
   patch -p0 -i ../../py_nonblocking.patch
}

build() {
   export _stagedir="${srcdir}/stagedir"
   local JOBS="$(sed -e 's/.*\(-j *[0-9]\+\).*/\1/' <<< ${MAKEFLAGS})"

   cd ${pkgbase}_${_boostver}

   ./bootstrap.sh --with-toolset=gcc --with-icu --with-python=/usr/bin/python2

   _bindir="bin.linuxx86"
   [[ "${CARCH}" = "x86_64" ]] && _bindir="bin.linuxx86_64"
   install -Dm755 tools/build/src/engine/$_bindir/b2 "${_stagedir}"/bin/b2

   # Add an extra python version. This does not replace anything and python 2.x
   # need to be the default.
   echo "using python : 3.4 : /usr/bin/python3 : /usr/include/python3.4m : /usr/lib ;" \
      >> project-config.jam

   # Support for OpenMPI
   echo "using mpi ;" >> project-config.jam

   # boostbook is needed by quickbook
   install -dm755 "${_stagedir}"/share/boostbook
   cp -a tools/boostbook/{xsl,dtd} "${_stagedir}"/share/boostbook/

   # default "minimal" install: "release link=shared,static
   # runtime-link=shared threading=single,multi"
   # --layout=tagged will add the "-mt" suffix for multithreaded libraries
   # and installs includes in /usr/include/boost.
   # --layout=system no longer adds the -mt suffix for multi-threaded libs.
   # install to ${_stagedir} in preparation for split packaging
   "${_stagedir}"/bin/b2 \
      variant=release \
      debug-symbols=off \
      threading=multi \
      runtime-link=shared \
      link=shared,static \
      toolset=gcc \
      python=2.7 \
      cflags="${CPPFLAGS} ${CFLAGS} -O3" linkflags="${LDFLAGS}" \
      --layout=system \
      --prefix="${_stagedir}" \
      ${JOBS} \
      install
}

package_boost58() {
   pkgdesc='Free peer-reviewed portable C++ source libraries - development headers'
   depends=("boost-libs58=${pkgver}")
   optdepends=('python: for python bindings'
               'python2: for python2 bindings'
               'boost-build: to use boost jam for building your project.')
   options=('staticlibs')

   install -dm755 "${pkgdir}"/usr
   cp -a "${_stagedir}"/{bin,include,share} "${pkgdir}"/usr

   install -d "${pkgdir}"/usr/lib
   cp -a "${_stagedir}"/lib/*.a "${pkgdir}"/usr/lib/

   ln -s /usr/bin/b2 "$pkgdir"/usr/bin/bjam
}

package_boost-libs58() {
   pkgdesc='Free peer-reviewed portable C++ source libraries - runtime libraries'
   depends=('bzip2' 'zlib' 'icu')
   optdepends=('openmpi: for mpi support')

   install -dm755 "${pkgdir}"/usr
   cp -a "${_stagedir}"/lib "${pkgdir}"/usr
   rm "${pkgdir}"/usr/lib/*.a
   find "${pkgdir}" -type l -delete
   find "${pkgdir}" -name mpi.so -delete
 }

# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: kevin <kevin@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Kritoke <kritoke@gamebox.net>
# Contributor: Luca Roccia <little_rock@users.sourceforge.net>

pkgbase=boost
pkgname=('boost-libs58') # 'boost58')
pkgver=1.58.0
_boostver=${pkgver//./_}
pkgrel=3
url='http://www.boost.org/'
arch=('i686' 'x86_64')
license=('custom')
makedepends=('icu>=55.1' 'python' 'python2' 'bzip2' 'zlib' 'openmpi')
source=(https://downloads.sourceforge.net/project/${pkgbase}/${pkgbase}/${pkgver}/${pkgbase}_${_boostver}.tar.bz2
        https://svn.boost.org/trac10/raw-attachment/ticket/10282/py_nonblocking.patch
        boost-1.58.0-Fix-for-bind-void-mf-ambiguous-resolution-error.patch)
sha1sums=('2fc96c1651ac6fe9859b678b165bd78dc211e881'
          '903ed0bfcc9f716127c60f7bf6a7e8c0d2ee9939'
          'f78d9c6a1ca0c073c21a74d01e6f72e3eb1d8d80')

prepare() {
   cd ${pkgbase}_${_boostver}

   patch -p2 -i ../boost-1.58.0-Fix-for-bind-void-mf-ambiguous-resolution-error.patch
   patch -p0 -i ../../py_nonblocking.patch
}

build() {
   export _stagedir="${srcdir}/stagedir"
   export _instdir="boost58"
   local JOBS="$(sed -e 's/.*\(-j *[0-9]\+\).*/\1/' <<< ${MAKEFLAGS})"

   cd ${pkgbase}_${_boostver}

   ./bootstrap.sh --with-toolset=gcc --with-icu --with-python=/usr/bin/python2

   _bindir="bin.linuxx86"
   [[ "${CARCH}" = "x86_64" ]] && _bindir="bin.linuxx86_64"
   install -Dm755 tools/build/src/engine/$_bindir/b2 "${_stagedir}"/bin/b2

   # Add an extra python version. This does not replace anything and python 2.x
   # need to be the default.
   echo "using python : 3.4 : /usr/bin/python3 : /usr/include/python3.4m : /usr/lib ;" \
      >> project-config.jam

   # Support for OpenMPI
   echo "using mpi ;" >> project-config.jam

   # boostbook is needed by quickbook

   # default "minimal" install: "release link=shared,static
   # runtime-link=shared threading=single,multi"
   # --layout=tagged will add the "-mt" suffix for multithreaded libraries
   # and installs includes in /usr/include/boost.
   # --layout=system no longer adds the -mt suffix for multi-threaded libs.
   # install to ${_stagedir} in preparation for split packaging
   "${_stagedir}"/bin/b2 \
      variant=release \
      debug-symbols=off \
      threading=multi \
      runtime-link=shared \
      link=shared,static \
      toolset=gcc \
      python=2.7 \
      cflags="${CPPFLAGS} ${CFLAGS} -O3" linkflags="${LDFLAGS}" \
      --layout=system \
      --prefix="${_stagedir}" \
      --libdir="${_stagedir}"/lib/$_instdir \
      --includedir="${_stagedir}"/include/$_instdir \
      ${JOBS} \
      install
}

#package_boost58() {
#   pkgdesc='Free peer-reviewed portable C++ source libraries - development headers'
#   depends=("boost-libs58=${pkgver}")
#   optdepends=('python: for python bindings'
#               'python2: for python2 bindings'
#               'boost-build: to use boost jam for building your project.')
#   options=('staticlibs')

#   install -dm755 "${pkgdir}"/usr
#   cp -a "${_stagedir}"/include "${pkgdir}"/usr

#   install -d "${pkgdir}"/usr/lib
#   cp -a "${_stagedir}"/lib/*.a "${pkgdir}"/usr/lib/

#   ln -s /usr/bin/b2 "$pkgdir"/usr/bin/bjam
#}

package_boost-libs58() {
   pkgdesc='Free peer-reviewed portable C++ source libraries - runtime libraries'
   depends=('bzip2' 'zlib' 'icu')
   optdepends=('openmpi: for mpi support')

   install -dm755 "${pkgdir}"/usr
   cp -a "${_stagedir}"/{include,lib} "${pkgdir}"/usr
   cp "${pkgdir}"/usr/lib/$_instdir/*.so.$pkgver "${pkgdir}"/usr/lib
 }